;**************************************************************************
;*
;* random (pokey) to pixel test
;*
;**************************************************************************
	
	org $2000			   ;prg start
	
	icl "custom.i"

START:

	
	;

	sei				  ;disable irqs
	lda	#$00
	sta	NMIEN			  ;NMIEN all off 
	sta	DMACTL			  ;DMACTL all off

	;set display list (use shadow regs)
	
	lda	#<displayList
	sta	DLISTL	
	lda	#>displayList
	sta	DLISTH
	
	;set display list interrupt
	  
	lda	#<dli_irq
        sta	VDSLSTL           
        lda	#>dli_irq
        sta	VDSLSTH    
	
	;vertical blank interrupt 
	
	lda 	#>vbi_irq
	sta	VVBLKIH	
	lda 	#<vbi_irq
	sta	VVBLKIL	
	
	;os key remove
	
	lda	#<noKeyRead
        sta	VSERINL        
        lda	#>noKeyRead
        sta	VSERINH        
		
	;color setup
	
	lda	#$0	
	sta	COLBK
	lda	#$4	
	sta	COLPF0
	lda	#$2	
	sta	COLPF1
	lda	#$6	
	sta	COLPF2
	lda	#$88				
	sta	COLPF3
				
	;disable player/missile dma
	
	lda	#$00
	sta	GRACTL
	
	;setup displays
	   
	lda	#DMACTL_DL|DMACTL_PF_NORMAL		
		
		;enable display list dma 			
		;playfield normal display (40)
			
	sta	DMACTL	;DMACTL
	
	lda	#$0
	sta	HSCROL
	
	;enable dli
	
	lda	#NMIEN_VBI|NMIEN_DLI
	sta	NMIEN	;VBI + DLI enbable
	
	lda	#$20	;1.79 MHz
	STA	AUDCTL  
	
	;
	
	cli		;irq enable

	

loop
	
	;Wait VBlank

;?WaitVC0
;        lda	VCOUNT		
;        beq	?WaitVC0   	
;?WaitVCnot0
;        lda	VCOUNT		
;        bne	?WaitVCnot0 

	
	ldx	#20
	ldy	#50
	lda	#1
	sta	zd0
	lda	#<charData
	sta	za0
	lda	#>charData
	sta	za0+1
	jsr	setPixel
	
	lda	#30
	sta	x0
	lda	#30
	sta	y0
	lda	#150
	sta	x1
	lda	#70
	sta	y1
	jsr	drawLine
	
	jmp loop			;end
	
;************************************************
;*
;* drawLine
;* 
;* x0 = zd4
;* x1 = zd5
;* y0 = zd6
;* y1 = zd7
;*	


.define x0	$d6	;zd4 .. zd15 space
.define x1	$d7
.define y0	$d8
.define y1	$d9

.define dx      $da	; |x1-x0|
.define dy      $db	; -|y1-y0|
.define sx      $dc             
.define sy      $dd              

.define errL    $de              
.define errH    $df   
.define e2L     $f0   
.define e2H     $f1   

drawLine
	
	;dx = abs(x1-x0); sx = x0<x1 ? +1 : -1
	
        lda x1
        sec
        sbc x0
        bpl @px
        eor #$FF
        clc
        adc #1
        ldx #$FF
        bne @px2
@px:    ldx #$01
@px2:   sta dx
        stx sx

	;dy = -abs(y1-y0); sy = y0<y1 ? +1 : -1
	
        lda y1
        sec
        sbc y0
        bpl @py
        eor #$FF
        clc
        adc #1
        ldx #$FF
        bne @py2
@py:    ldx #$01
@py2:   ;a = abs(y1-y0)
        eor #$FF              ; dy = -abs(...)
        clc
        adc #1
        sta dy
        stx sy

	;err = dx + dy   (dy is negative	, sign-extend)
	
        lda dx
        sta errL
        lda #$00
        sta errH

        lda dy
        clc
        adc errL
        sta errL
        lda #$FF             ;high from negative dy
        adc errH
        sta errH
	
@drawLoop:

	;draw pixel

	ldx	x0
	ldy	y0
	lda	#1
	sta	zd0
	lda	#<charData
	sta	za0
	lda	#>charData
	sta	za0+1
	jsr	setPixel

	;e2 = 2*err
        lda errL
        asl
        sta e2L
        lda errH
        rol
        sta e2H

	;if e2 >= dy { err += dy; x0 += sx }
	;-> signed compare: (e2 - dy16) >= 0 ?
	
        lda e2L
        sec
        sbc dy
        lda e2H
        sbc #$FF
        bmi @skipX
	
        ; do X-step
	
        lda errL
        clc
        adc dy
        sta errL
        lda errH
        adc #$FF
        sta errH

        lda x0
        clc
        adc sx
        sta x0
@skipX:

	;if e2 <= dx { err += dx; y0 += sy }
	;-> signed compare: (e2 - dx16) <= 0 ?
        lda e2L
        sec
        sbc dx
        lda e2H
        sbc #$00
        bpl @gtDX              ; >0 -> skip Y
        ; do Y-step (<=0)
        lda errL
        clc
        adc dx
        sta errL
        lda errH
        adc #$00
        sta errH

        lda y0
        clc
        adc sy
        sta y0
@gtDX:

	;finish?
        lda x0
        cmp x1
        bne @drawLoop
        lda y0
        cmp y1
        bne @drawLoop	
    
	rts
	
;************************************************
;*
;* setPixel
;* 
;* x   = xpos (0..159)
;* y   = ypos (0..95)
;* zd0 = 0 is clear pixel otherwise set pixel
;* za0 = dest (gfx)
;*
;* waste x,y,za0
;*
;************************************************

setPixel
	
	tya			;a = y
	asl			;* 2
	tay
	lda	?pixelYTable,y	;get y offset low
	clc
	adc	za0
	sta	za0
	iny
	lda	?pixelYTable,y	;get y offset high
	adc	za0+1
	sta	za0+1		;16 bit add to dest address
	
	txa
	and	#$7		;&7	
	tay			;store (y = x)
	
	txa
	lsr
	lsr
	lsr			;x / 8
	
	clc
	adc	za0
	sta	za0
	lda	za0+1
	adc	#0
	sta	za0+1		;add to dest address

	;tay
	ldx	#0	
	lda	zd0
	beq	?clearPixel
	
	;set pixel
	
	lda	(za0,x)	
	ora	?pixelMask,y
	sta	(za0,x)	
	rts
	
?clearPixel	
	;clear pixel
	
	lda	(za0,x)	
	and	?pixelNotMask,y
	sta	(za0,x)	
	rts

?pixelMask

    .byte %10000000
    .byte %01000000
    .byte %00100000
    .byte %00010000
    .byte %00001000
    .byte %00000100
    .byte %00000010
    .byte %00000001
    
?pixelNotMask

    .byte %01111111
    .byte %10111111
    .byte %11011111
    .byte %11101111
    .byte %11110111
    .byte %11111011
    .byte %11111101
    .byte %11111110    
    
?pixelYTable 	.rept	96
		.word	#*20
		.endr
			


;************************************************
;*
;* dummy
;*
;************************************************
	
noKeyRead	
	rts
	
;************************************************
;*
;* vertical blank interrupt (immidiate, x,y regs save bei os rom)
;*
;************************************************

vbi_irq

	;
	
	lda	#0
	sta	dliCounter
	
	;prolog (like XITVBL)
	
	pla					  
	tay
	pla					  
	tax
	pla					  
	rti
			
;************************************************
;*
;* display list interrupt
;*
;************************************************

dli_irq

	;prolog

        pha 
	txa	
	pha
	tya	
	pha
		
	;epilog
	
        pla					  
	tay
	pla					  
	tax
	pla
        rti   	;direct (no stack used)
	
	
dliCounter	.byte	0

; display list

	;7	6	5	4	3	2	1	0
	;DLI	LMS	VSCROLL	HSCOLL	Mode
	;
	;Mode 0 Blank lines 7..4 is count+1 of blank lines
	;Mode 1 JMP (use with LMS to set destination)
	;Mode $2-$f is ANTIC mode

	.align $400
	
displayList	 
	.byte 0			;Mode 0
	.byte $70		;8 blank lines	
	.byte $70		;8 blank lines
	.byte $70  		;DLI 8 blank lines
	.byte $4b,<charData,>charData   	;Mode b + LMS
	.rept 95
	.byte $b
	.endr
	.byte $41,<displayList,>displayList ; wait vblank, restart same display list on next frame	
	
	org	$4000
	 	
charData

	;160 x 96 (1bit)
	
	.byte	0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff
	.rept	94
	.byte	0x80,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x01
	.endr
	.byte	0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff,0xff